home *** CD-ROM | disk | FTP | other *** search
/ SGI Hot Mix 17 / Hot Mix 17.iso / HM17_SGI / research / examples / demo / demosrc / d_vibmembr.pro < prev    next >
Text File  |  1997-07-08  |  71KB  |  1,976 lines
  1. $Id: d_vibmembr.pro,v 1.19 1997/04/19 22:48:46 tremblay Exp $
  2. ;
  3. ;  Copyright (c) 1997, Research Systems, Inc. All rights reserved.
  4. ;       Unauthorized reproduction prohibited.
  5. ;
  6. ;+
  7. ;  FILE:
  8. ;       d_vibmembr.pro
  9. ;
  10. ;  CALLING SEQUENCE: d_vibmembr
  11. ;
  12. ;  PURPOSE:
  13. ;       Shows an animation of a vibrating membrane in IDL 5.0.
  14. ;
  15. ;  MAJOR TOPICS: Visualization.
  16. ;
  17. ;  CATEGORY:
  18. ;       IDL 5.0
  19. ;
  20. ;  INTERNAL FUNCTIONS and PROCEDURES:
  21. ;       pro vib_setShades           - Set the shading colors overlay
  22. ;       fun toggle_state        - Toggle  off/on name
  23. ;       fun cw_iat              - Compound widget : animation tool in 5.0
  24. ;       pro vibmembr_Event      - Event handler
  25. ;       pro vibmembr_Cleanup    - Cleanup
  26. ;       pro d_vibmembr               - Main procedure
  27. ;
  28. ;  EXTERNAL FUNCTIONS, PROCEDURES, and FILES:
  29. ;       pro iniobj              - Create the objects
  30. ;       pro vibmem              - Compute the vibrating membrane (main surface)
  31. ;       pro bumps               - Compute 2-D wave data set for shading color
  32. ;       pro cw_iat              - Compound widget animation tool in 5.0.
  33. ;       pro trackball__define   - Create the trackball object
  34. ;       fun gettips             - Read the tip file
  35. ;       pro widtips             - Create the tip widgets text
  36. ;       pro sizetips            - Size the tip widgets text
  37. ;       pro trackball__define   - Create the trackball object
  38. ;       vibmembr.txt
  39. ;       vibmembr.tip
  40. ;
  41. ;  REFERENCE: IDL Reference Guide, IDL User's Guide
  42. ;
  43. ;  NAMED STRUCTURES:
  44. ;       none.
  45. ;
  46. ;  COMMON BLOCS:
  47. ;       none.
  48. ;
  49. ;  MODIFICATION HISTORY: Written by DAT,RSI,  July 1996 New GUI
  50. ;                        vibmem.pro written by Steve Kranock, RSI, 1996
  51. ;
  52. ;-
  53. ; -----------------------------------------------------------------------------
  54. ;
  55. ;  Purpose:  Set the shading colors.
  56. ;            This procedure changes the vertices (shades) colors. When
  57. ;            the input initial is less that final, the colors are those
  58. ;            that corresponds to the surface height ( 4-D). Otherwise,
  59. ;            the colors frames are set in an inverse order ( this gives a
  60. ;            6-D mode.
  61. ;
  62.  
  63. FUNCTION bumps,  $
  64.     kindex      ; IN: time index
  65.     
  66.     ;  Create a 2-d time dependent wave function.
  67.     ;
  68.     ;  2 harmonics in th x direction,
  69.     ;  2 harmonics in th y direction
  70.     ;  the z direction is the product of
  71.     ;  the x and y waves...
  72.     ;
  73.  
  74.     ;  Initialize constants
  75.     ;
  76.     kvect = fltarr(4)
  77.     kvect = [10.0, 16.4, 13.0, 11.4]
  78.     kvect = kvect/200 
  79.  
  80.     k = kindex
  81.  
  82.     time =   2.05 * !pi* (0.6 - 0.3*cos(float(k)/100.))
  83.  
  84.     nk = float(k)/10.0 * (-0.7) 
  85.  
  86.     ;  The data set has diumension  ndim x ndim.
  87.     ;
  88.     ndim = 21
  89.  
  90.     wvect = kvect * time
  91.  
  92.     a1 = 1.0
  93.     a2 = 1.0
  94.     a3 = 1.0
  95.     a4 = 1.0
  96.     b1 = 1.0
  97.     b2 = 1.0
  98.     b3 = 1.0
  99.     b4 = 1.0
  100.  
  101.     x = FINDGEN(ndim)*2
  102.     y = FINDGEN(ndim)*2
  103.     z = fltarr(ndim,ndim)
  104.  
  105.     z = z - z
  106.  
  107.     for i = 0, ndim-1 do begin
  108.         for j = 0, ndim-1  do begin
  109.              z(i,j) = z(i,j) + (  a1*cos(wvect(0)*x(i)+nk) + $    
  110.                    b1*sin(wvect(0)*x(i)+nk) + $    
  111.                    a2*cos(wvect(1)*x(i)+nk) + $    
  112.                    b2*sin(wvect(1)*x(i)+nk)  ) *  $
  113.                   (a3*cos(wvect(2)*y(j)+2.0*nk) + $    
  114.                    b3*sin(wvect(2)*y(j)+2.0*nk) + $    
  115.                    a4*cos(wvect(3)*y(j)+2.0*nk) + $    
  116.                    b4*sin(wvect(3)*y(j)+2.0*nk)  ) 
  117.         endfor
  118.     endfor
  119.          
  120.     RETURN, z
  121.  
  122. end   ;
  123.  
  124. ; $Id: cw_iat.pro,v 
  125. ;
  126. ;  Copyright (c) 1997, Research Systems, Inc. All rights reserved.
  127. ;       Unauthorized reproduction prohibited.
  128. ;
  129. ;+
  130. ;  FILE:
  131. ;       cw_iat.pro
  132. ;
  133. ;  CALLING SEQUENCE: cw_iat
  134. ;
  135. ;  PURPOSE:
  136. ;       Compoihnd widget of the animation tool in IDL 5.0.
  137. ;
  138. ;  MAJOR TOPICS: Visualization and animation.
  139. ;
  140. ;  CATEGORY:
  141. ;       IDL 5.0
  142. ;
  143. ;  INTERNAL FUNCTIONS and PROCEDURES:
  144. ;       fun getRotation         - Rotation values of the satellite
  145. ;       fun createSatellite     - create the satellite object
  146. ;       fun findE               - Compute the eccentric anomaly
  147. ;       fun findPosition        - Compute the satelitte's ephemeris.
  148. ;       pro orbit_Event         - Event handler
  149. ;       pro orbit_Cleanup       - Cleanup
  150. ;       pro orbit               - Main procedure
  151. ;
  152. ;  EXTERNAL FUNCTIONS, PROCEDURES, and FILES:
  153. ;       pro trackball__define   - Create the trackball object
  154. ;
  155. ;  REFERENCE: IDL Reference Guide, IDL User's Guide
  156. ;
  157. ;  NAMED STRUCTURES:
  158. ;       none.
  159. ;
  160. ;  COMMON BLOCS:
  161. ;       none.
  162. ;
  163. ;  MODIFICATION HISTORY: Written by DAT,RSI,  July 1996 New GUI
  164. ;                        Modified by DAT, RSI, february 1997, add 
  165. ;                        trackball object and cleanup the code.
  166. ;
  167. ;-
  168. ;---------------------------------------------------------------------------
  169. ;
  170. ;  Purpose:  On realization of the main base (outside this CW), assigns
  171. ;            the widow object to the parent of the widget draw.
  172. ;
  173. pro DRAW1CB, $
  174.     sEvent      ; IN: event structure.
  175.  
  176.     WIDGET_CONTROL, sEvent, GET_VALUE = oWindow
  177.     wRightBase = WIDGET_INFO(sEvent, /PARENT)
  178.     WIDGET_CONTROL, wRightBase, SET_UVALUE =oWindow , /NO_COPY
  179. end
  180.  
  181. ;---------------------------------------------------------------------------
  182. ;
  183. ;  Purpose:  Event handler for events occuring within the compound widget.
  184. ;            these event are : bitmap buttons, frame speed slider,
  185. ;            frame indicator slider, and the reset button.
  186. ;
  187. pro cw_iatEvent, $
  188.     sEvent      ; IN: event structure.
  189.  
  190.     ;  Get the drawWindow object identifier
  191.     ;  which is the user value of the right base.
  192.     ;
  193.     child = WIDGET_INFO(sEvent.handler, /CHILD)
  194.     WIDGET_CONTROL, child, GET_UVALUE = sState, /NO_COPY
  195.     WIDGET_CONTROL, sState.wRightBase, $
  196.         GET_UVALUE=temp, /NO_COPY
  197.     oWindow = temp
  198.     WIDGET_CONTROL, sState.wRightBase, $
  199.         SET_UVALUE=temp, /NO_COPY
  200.     WIDGET_CONTROL, child, SET_UVALUE=sState, /NO_COPY
  201.  
  202.     WIDGET_CONTROL, sEvent.id, GET_UVALUE= uValue
  203.  
  204.     ;  Branch to the appropriate event.
  205.     ;
  206.     case uValue of 
  207.         'ACTIVE' : begin
  208.  
  209.             ;  Toggle the active button.
  210.             ;
  211.             WIDGET_CONTROL, child, GET_UVALUE=sState, /NO_COPY
  212.             WIDGET_CONTROL, sState.wActiveButton, GET_VALUE=activeFlag
  213.             sState.activeFlag = activeFlag
  214.  
  215.             if (sState.activeFlag EQ 1) then begin
  216.                 WIDGET_CONTROL, sState.wFramesIndicatorSlider, $
  217.                    SET_VALUE=sState.frameIndex
  218.  
  219.                 if (sState.stopFlag EQ 1)  then begin
  220.                     WIDGET_CONTROL, sState.wFramesIndicatorSlider, $
  221.                         SENSITIVE=1
  222.                 endif
  223.             endif else begin
  224.                 WIDGET_CONTROL, sState.wFramesIndicatorSlider, $
  225.                     SENSITIVE=0
  226.             endelse
  227.  
  228.             WIDGET_CONTROL, child, SET_UVALUE=sState, /NO_COPY
  229.  
  230.         end     ;  of  ACTIVE
  231.  
  232.         ;  The timer event create the loop because another timer event
  233.         ;  is generated given that the stop button has not been pushed.
  234.         ;
  235.         'TIMER' : begin
  236.  
  237.             WIDGET_CONTROL, child, GET_UVALUE=sState, /NO_COPY
  238.  
  239.             stopFlag = sState.stopFlag
  240.  
  241.             ;  Animate only if the stop flag has not been pushed
  242.             ;  ( i.e. stopflag = 0).
  243.             ; 
  244.             if (stopFlag EQ 0) then begin
  245.  
  246.                 ;  Hide the previous frame (model).
  247.                 ;
  248.                 i = sState.previousIndex
  249.                 sState.oMovableModelArray(i)->SetProperty, HIDE=1
  250.                 sState.oStaticModelArray(i)->SetProperty, HIDE=1
  251.  
  252.                 sState.frameIndex = sState.frameIndex + $
  253.                     sState.frameIncrement
  254.                 sState.currentIndex = sState.frameIndex
  255.                 if (sState.cycleFlag EQ 0 ) then begin
  256.                     ;  Reset the frame index , First if not in cycle mode.
  257.                     ;
  258.                     if (sState.frameIndex EQ sState.nframes) then begin
  259.                         sState.frameIndex = 0
  260.                     endif
  261.                     if (sState.frameIndex LT 0) then begin
  262.                         sState.frameIndex = sState.nframes-1
  263.                     endif
  264.                 endif else begin  
  265.                     ;  Reset the frame index if in
  266.                     ;  cycle mode ( back and forth).
  267.                     ;
  268.                     if (( sState.frameIndex EQ (sState.nframes)) OR $
  269.                         (sState.frameIndex EQ -1) ) then begin
  270.                         sState.frameIncrement = -sState.frameIncrement
  271.                         sState.frameIndex = sState.frameIndex + $
  272.                             2*sState.frameIncrement
  273.                     endif
  274.                 endelse
  275.  
  276.                 ;  Draw the current frame.
  277.                 ;
  278.                 i = sState.frameIndex
  279.                 sState.oMovableModelArray(i)->SetProperty, HIDE=0
  280.                 sState.oStaticModelArray(i)->SetProperty, HIDE=0
  281.                 oWindow->Draw, sState.oView
  282.                 sState.previousIndex = i
  283.  
  284.                 if (sState.activeFlag EQ 1) then begin
  285.                     WIDGET_CONTROL, sState.wFramesIndicatorSlider, $
  286.                         SET_VALUE= sState.frameIndex
  287.                 endif
  288.  
  289.                 ;  Accumulate the number of frames to compute
  290.                 ;  the frame rate.
  291.                 ;
  292.                 sState.count = sState.count + 1
  293.  
  294.                 ;  If count is 5 , reset it zero,
  295.                 ;  Display the frame rate.
  296.                 ;
  297.                 if (sState.count EQ 5) then begin
  298.                     sState.finalTime = SYSTIME(1)
  299.                     delta = sState.finalTime - sState.startTime
  300.                     rate = FLOAT(5.0/ delta)
  301.                     WIDGET_CONTROL, sState.wFramesRateLabel, $
  302.                        SET_VALUE= STRING(rate, FORMAT='(f6.2)' )
  303.                     sState.count = 0
  304.                     sState.startTime = sState.finalTime
  305.                 endif
  306.  
  307.                 WIDGET_CONTROL, sState.wButtonBase, $
  308.                     TIMER=1.0e-4 + sState.delay
  309.                 sState.previousIndex = sState.frameIndex
  310.  
  311.             endif  ; of StopFlag = 0
  312.  
  313.             WIDGET_CONTROL, child, SET_UVALUE=sState, /NO_COPY
  314.  
  315.         end     ;   of  TIMER
  316.  
  317.         ;  Handle the play forward button.
  318.         ;
  319.         'PLAYFORWARD' : begin
  320.             WIDGET_CONTROL, child, GET_UVALUE=sState, /NO_COPY
  321.             if( sState.forwardFlag EQ 0) then begin
  322.                 if(sState.stopflag EQ 1) then begin
  323.                     sState.count = 0
  324.                     sState.startTime = systime(1)
  325.                     WIDGET_CONTROL, sState.wFramesIndicatorSlider, $
  326.                         SENSITIVE=0
  327.                 endif
  328.  
  329.                 sState.frameIncrement = 1
  330.                 sState.cycleFlag = 0
  331.                 sState.forwardFlag = 1
  332.                 sState.backwardFlag = 0
  333.                 sState.stopFlag = 0    
  334.                 if (sState.frameIndex EQ sState.nframes-1) $
  335.                     then sState.frameIndex = 0
  336.                 ;  The stop button has not been pushed.
  337.                 ;
  338.                 sState.stopFlag = 0  
  339.                 WIDGET_CONTROL, sState.wplayFButton, $
  340.                     SET_VALUE=sState.BMB.forwardOn
  341.                 WIDGET_CONTROL, sState.wplayBButton, $
  342.                     SET_VALUE=sState.BMB.backward
  343.                 WIDGET_CONTROL, sState.wCycleButton, $
  344.                     SET_VALUE=sState.BMB.cycle
  345.                 WIDGET_CONTROL, sState.wStopButton, $
  346.                     SET_VALUE=sState.BMB.stop
  347.                 WIDGET_CONTROL, sState.wButtonBase, $
  348.                     TIMER=1.0e-4 + sState.delay
  349.             endif
  350.             WIDGET_CONTROL, child, SET_UVALUE=sState, /NO_COPY
  351.         end   ; of PLAYFORWARD
  352.  
  353.         ;  Handle the play forward button.
  354.         ;
  355.         'PLAYBACKWARD' : begin
  356.             WIDGET_CONTROL, child, GET_UVALUE=sState, /NO_COPY
  357.             if (sState.backwardFlag EQ 0) then begin
  358.                 if (sState.frameIndex EQ 0) then $
  359.                     sState.frameIndex = sState.nframes-1
  360.                 if(sState.stopflag EQ 1) then begin
  361.                     sState.count = 0
  362.                     sState.startTime = systime(1)
  363.                     WIDGET_CONTROL, sState.wFramesIndicatorSlider, $
  364.                         SENSITIVE=0
  365.                 endif
  366.  
  367.                 sState.cycleFlag = 0
  368.                 sState.forwardFlag = 0
  369.                 sState.backwardFlag = 1
  370.                 sState.stopFlag = 0    
  371.                 sState.frameIncrement = -1
  372.                 WIDGET_CONTROL, sState.wplayFButton, $
  373.                     SET_VALUE=sState.BMB.forward
  374.                 WIDGET_CONTROL, sState.wplayBButton, $
  375.                     SET_VALUE=sState.BMB.backwardOn
  376.                 WIDGET_CONTROL, sState.wCycleButton, $
  377.                     SET_VALUE=sState.BMB.cycle
  378.                 WIDGET_CONTROL, sState.wStopButton, $
  379.                     SET_VALUE=sState.BMB.stop
  380.                 WIDGET_CONTROL, sState.wButtonBase, $
  381.                     TIMER=1.0e-4 + sState.delay
  382.             endif
  383.             WIDGET_CONTROL, child, SET_UVALUE=sState, /NO_COPY
  384.         end   ; of PLAYBACKWARD
  385.  
  386.         ;  Handle the top button(stops the animation).
  387.         ;
  388.         'STOP' : begin
  389.             WIDGET_CONTROL, child, GET_UVALUE=sState, /NO_COPY
  390.             if( sState.stopFlag EQ 0) then begin
  391.                 sState.cycleFlag = 0
  392.                 sState.forwardFlag = 0
  393.                 sState.backwardFlag = 0
  394.                 sState.stopFlag = 1    
  395.                 WIDGET_CONTROL, sState.wAreaDraw, DRAW_MOTION = 0
  396.                 WIDGET_CONTROL, sState.wplayFButton, $
  397.                     SET_VALUE=sState.BMB.forward
  398.                 WIDGET_CONTROL, sState.wplayBButton, $
  399.                     SET_VALUE=sState.BMB.backward
  400.                 WIDGET_CONTROL, sState.wCycleButton, $
  401.                     SET_VALUE=sState.BMB.cycle
  402.                 WIDGET_CONTROL, sState.wStopButton, $
  403.                     SET_VALUE=sState.BMB.stopOn
  404.                 if (sState.wResetButton NE 0L) then begin
  405.                     WIDGET_CONTROL, sState.wResetButton, SENSITIVE=1
  406.                 endif
  407.                 if (sState.activeFlag EQ 1) then begin
  408.                     WIDGET_CONTROL, sState.wFramesIndicatorSlider, $
  409.                         SENSITIVE=1
  410.                 endif else begin
  411.                     WIDGET_CONTROL, sState.wFramesIndicatorSlider, $
  412.                         SENSITIVE=0
  413.                 endelse
  414.             endif
  415.             WIDGET_CONTROL, child, SET_UVALUE=sState, /NO_COPY
  416.             RETURN
  417.         end  ; of STOP
  418.  
  419.         ;  Play back and forth (cycle) button.
  420.         ;
  421.         'CYCLE' : begin
  422.             WIDGET_CONTROL, child, GET_UVALUE=sState, /NO_COPY
  423.             if (sState.cycleFlag EQ 0) then begin
  424.                 if (sState.stopflag EQ 1) then begin
  425.                     sState.count = 0
  426.                     sState.startTime = SYSTIME(1)
  427.                     WIDGET_CONTROL, sState.wFramesIndicatorSlider, $
  428.                         SENSITIVE=0
  429.                 endif
  430.                 sState.cycleFlag = 1
  431.                 sState.forwardFlag = 0
  432.                 sState.backwardFlag = 0
  433.                 sState.stopFlag = 0    
  434.                 WIDGET_CONTROL, sState.wplayFButton, $
  435.                     SET_VALUE=sState.BMB.forward
  436.                 WIDGET_CONTROL, sState.wplayBButton, $
  437.                     SET_VALUE=sState.BMB.backward
  438.                 WIDGET_CONTROL, sState.wCycleButton, $
  439.                     SET_VALUE=sState.BMB.cycleOn
  440.                 WIDGET_CONTROL, sState.wStopButton, $
  441.                     SET_VALUE=sState.BMB.stop
  442.                 WIDGET_CONTROL, sState.wButtonBase, $
  443.                     TIMER=1.0e-4 + sState.delay
  444.             endif
  445.             WIDGET_CONTROL, child, SET_UVALUE=sState, /NO_COPY
  446.         end   ; of CYCLE
  447.  
  448.         ;  Reset the initial orientation of the display and
  449.         ;  show the first frame (frame index = 0).
  450.         ;
  451.         'RESET': begin
  452.  
  453.             ;  Reset to the first frame (if play mode was forward), or
  454.             ;  to the last frame ( if play mode was backward). Also
  455.             ;  restore the initial tranformation matrix.
  456.             ;
  457.             WIDGET_CONTROL, child, GET_UVALUE = sState, /NO_COPY
  458.  
  459.             if (sState.frameIncrement EQ 1) then begin
  460.                 sState.frameIndex = 0
  461.                 WIDGET_CONTROL, sState.wFramesIndicatorSlider, $
  462.                     SET_VALUE=0
  463.                 i = 0
  464.             endif else begin
  465.                 sState.frameIndex = sState.nframes-1
  466.                 i = sState.nframes-1
  467.                 WIDGET_CONTROL, sState.wFramesIndicatorSlider, $
  468.                     SET_VALUE = sState.nframes-1
  469.             endelse
  470.  
  471.             j=i
  472.             sState.oMovableRotationModel->SetProperty, $
  473.                 TRANSFORM=sState.initTransform
  474.             for i = 0, sState.nframes - 1 do begin
  475.                 sState.oMovableModelArray(i)->SetProperty, HIDE=1
  476.                 sState.oStaticModelArray(i)->SetProperty, HIDE=1
  477.             endfor
  478.  
  479.             sState.oMovableModelArray(j)->SetProperty, HIDE=0
  480.  
  481.             sState.oStaticModelArray(j)->SetProperty, HIDE=0
  482.             sState.previousIndex = j
  483.             oWindow->Draw, sState.oView
  484.             WIDGET_CONTROL, child, SET_UVALUE=sState, /NO_COPY
  485.         end   ; of RESET
  486.  
  487.         ;  Responds for cursor event in the draw area.
  488.         ;
  489.         'DRAWING': begin
  490.  
  491.             WIDGET_CONTROL, child, GET_UVALUE=sState, /NO_COPY
  492.  
  493.             ;  Expose.
  494.             ;
  495.             if (sEvent.type EQ 4) then begin
  496.                 oWindow->Draw, sState.oView
  497.                 WIDGET_CONTROL, child, SET_UVALUE = sState, /NO_COPY
  498.                 RETURN
  499.             endif
  500.  
  501.             ;  Handle trackball update.
  502.             ;
  503.             bHaveTransform = sState.oTrack->Update(sEvent, $
  504.                 TRANSFORM=qmat)
  505.             if (bHaveTransform NE 0) then begin
  506.                 sState.oMovableRotationModel->GetProperty, TRANSFORM=t
  507.                 mt = t # qmat
  508.                 sState.oMovableRotationModel->SetProperty, TRANSFORM=mt
  509.             endif
  510.  
  511.             ;  Handle button press here.
  512.             ;
  513.             if (sEvent.type EQ 0) then begin
  514.                 sState.btndown = 1B
  515.                 oWindow->SetProperty, QUALITY=sState.dragq
  516.                 WIDGET_CONTROL,sState.wAreaDraw, /DRAW_MOTION
  517.             endif
  518.  
  519.             ;  Handle draw motion here.
  520.             ;
  521.             if ((sEvent.type EQ 2) and (sState.btndown EQ 1b)) $
  522.                 then begin
  523.                 if (bHaveTransform) then $
  524.                     oWindow->Draw, sState.oView
  525.             endif
  526.  
  527.             ;  Handle release button here.
  528.             ;
  529.             if (sEvent.type EQ 1) then begin
  530.                 if (sState.btndown EQ 1B) then begin
  531.                     oWindow->SetProperty, QUALITY=2
  532.                     oWindow->Draw, sState.oView
  533.                 endif
  534.                 sState.btndown = 0B
  535.                 WIDGET_CONTROL, sState.wAreaDraw, DRAW_MOTION=0
  536.             endif
  537.  
  538.             WIDGET_CONTROL, child, SET_UVALUE = sState, /NO_COPY
  539.  
  540.         end   ; of DRAWING
  541.  
  542.         ;  Reset the delay between frames using the speed slider.
  543.         ;
  544.         'SPEED' : begin
  545.             WIDGET_CONTROL, child, GET_UVALUE=sState, /NO_COPY
  546.             WIDGET_CONTROL, sState.wFramesSpeedSlider, $
  547.                 GET_VALUE=speedvalue
  548.             if (speedvalue EQ 100) then begin
  549.                 sState.delay = 0.0
  550.             endif else begin
  551.                 sState.delay = 3.0 / (3.0 + speedvalue )
  552.             endelse
  553.             WIDGET_CONTROL, child, SET_UVALUE=sState, /NO_COPY
  554.         end    ;  of SPEED
  555.  
  556.         ;  Display the frame selected by the indicator slider.
  557.         ;
  558.         'INDICATOR': begin
  559.             WIDGET_CONTROL, child, GET_UVALUE=sState, /NO_COPY
  560.             wCWBase = sState.wCWBase
  561.             WIDGET_CONTROL, sState.wFramesIndicatorSlider, $
  562.                 GET_VALUE = frameIndex
  563.  
  564.             i = sState.previousIndex
  565.             sState.oMovableModelArray(i)->SetProperty, HIDE=1
  566.             sState.oStaticModelArray(i)->SetProperty, HIDE=1
  567.  
  568.             sState.frameIndex = frameIndex
  569.             sState.previousIndex = frameIndex
  570.             sState.oMovableModelArray(frameIndex)->SetProperty, HIDE=0
  571.             sState.oStaticModelArray(frameIndex)->SetProperty, HIDE=0
  572.             oWindow->Draw, sState.oView
  573.             WIDGET_CONTROL, child, SET_UVALUE=sState, /NO_COPY
  574.  
  575.             ;  We may return here because the  frame indicator slider
  576.             ;  is not sensitized while in a playing mode. 
  577.             ;
  578.             RETURN
  579.         end   ; of INDICATOR
  580.  
  581.     endcase   ; of case widget_info(name)
  582.  
  583. end  ; of cw_iatEvent
  584.  
  585. ;---------------------------------------------------------------------------
  586. ;
  587. ;  Purpose:  Initialize (create) the bitmap buttons.
  588. ;
  589. function InitBitmapButtons
  590.  
  591.     stop = [[000B, 000B, 000B],[000B, 000B, 000B],$
  592.             [000B, 000B, 000B],[000B, 000B, 000B],$
  593.             [240B, 255B, 015B],[240B, 255B, 015B],$
  594.             [240B, 255B, 015B],[112B, 000B, 014B],$
  595.             [112B, 255B, 014B],[112B, 255B, 014B],$
  596.             [112B, 255B, 014B],[112B, 255B, 014B],$
  597.             [112B, 255B, 014B],[112B, 255B, 014B],$
  598.             [112B, 255B, 014B],[112B, 255B, 014B],$
  599.             [112B, 000B, 014B],[240B, 255B, 015B],$
  600.             [240B, 255B, 015B],[240B, 255B, 015B],$
  601.             [000B, 000B, 000B],[000B, 000B, 000B],$
  602.             [000B, 000B, 000B],[000B, 000B, 000B]]
  603.  
  604.     stopon = [[255B, 255B, 255B],[255B, 255B, 255B],$
  605.               [255B, 255B, 255B],[255B, 255B, 255B],$
  606.               [015B, 000B, 240B],[015B, 000B, 240B],$
  607.               [015B, 000B, 240B],[143B, 255B, 241B],$
  608.               [143B, 000B, 241B],[143B, 000B, 241B],$
  609.               [143B, 000B, 241B],[143B, 000B, 241B],$
  610.               [143B, 000B, 241B],[143B, 000B, 241B],$
  611.               [143B, 000B, 241B],[143B, 000B, 241B],$
  612.               [143B, 255B, 241B],[015B, 000B, 240B],$
  613.               [015B, 000B, 240B],[015B, 000B, 240B],$
  614.               [255B, 255B, 255B],[255B, 255B, 255B],$
  615.               [255B, 255B, 255B],[255B, 255B, 255B]]
  616.  
  617.     forward = [[000B, 000B, 000B],[000B, 000B, 000B],$
  618.                [000B, 000B, 000B],[056B, 000B, 000B],$
  619.                [248B, 000B, 000B],[248B, 003B, 000B],$
  620.                [248B, 015B, 000B],[248B, 063B, 000B],$
  621.                [248B, 255B, 000B],[248B, 255B, 003B],$
  622.                [248B, 255B, 015B],[248B, 255B, 031B],$
  623.                [248B, 255B, 031B],[248B, 255B, 015B],$
  624.                [248B, 255B, 003B],[248B, 255B, 000B],$
  625.                [248B, 063B, 000B],[248B, 015B, 000B],$
  626.                [248B, 003B, 000B],[248B, 000B, 000B],$
  627.                [056B, 000B, 000B],[000B, 000B, 000B],$
  628.                [000B, 000B, 000B],[000B, 000B, 000B]]
  629.  
  630.     forwardOn = [[255B, 255B, 255B],[255B, 255B, 255B],$
  631.                  [255B, 255B, 255B],[199B, 255B, 255B],$
  632.                  [007B, 255B, 255B],[007B, 252B, 255B],$
  633.                  [007B, 240B, 255B],[007B, 192B, 255B],$
  634.                  [007B, 000B, 255B],[007B, 000B, 252B],$
  635.                  [007B, 000B, 240B],[007B, 000B, 224B],$
  636.                  [007B, 000B, 224B],[007B, 000B, 240B],$
  637.                  [007B, 000B, 252B],[007B, 000B, 255B],$
  638.                  [007B, 192B, 255B],[007B, 240B, 255B],$
  639.                  [007B, 252B, 255B],[007B, 255B, 255B],$
  640.                  [199B, 255B, 255B],[255B, 255B, 255B],$
  641.                  [255B, 255B, 255B],[255B, 255B, 255B]]
  642.  
  643.     backward = [[000B, 000B, 000B],[000B, 000B, 000B],$
  644.                 [000B, 000B, 000B],[000B, 000B, 028B],$
  645.                 [000B, 000B, 031B],[000B, 192B, 031B],$
  646.                 [000B, 240B, 031B],[000B, 252B, 031B],$
  647.                 [000B, 255B, 031B],[192B, 255B, 031B],$
  648.                 [240B, 255B, 031B],[248B, 255B, 031B],$
  649.                 [248B, 255B, 031B],[240B, 255B, 031B],$
  650.                 [192B, 255B, 031B],[000B, 255B, 031B],$
  651.                 [000B, 252B, 031B],[000B, 240B, 031B],$
  652.                 [000B, 192B, 031B],[000B, 000B, 031B],$
  653.                 [000B, 000B, 028B],[000B, 000B, 000B],$
  654.                 [000B, 000B, 000B],[000B, 000B, 000B]]
  655.  
  656.     backwardOn = [[255B, 255B, 255B],[255B, 255B, 255B],$
  657.                   [255B, 255B, 255B],[255B, 255B, 227B],$
  658.                   [255B, 255B, 224B],[255B, 063B, 224B],$
  659.                   [255B, 015B, 224B],[255B, 003B, 224B],$
  660.                   [255B, 000B, 224B],[063B, 000B, 224B],$
  661.                   [015B, 000B, 224B],[007B, 000B, 224B],$
  662.                   [007B, 000B, 224B],[015B, 000B, 224B],$
  663.                   [063B, 000B, 224B],[255B, 000B, 224B],$
  664.                   [255B, 003B, 224B],[255B, 015B, 224B],$
  665.                   [255B, 063B, 224B],[255B, 255B, 224B],$
  666.                   [255B, 255B, 227B],[255B, 255B, 255B],$
  667.                   [255B, 255B, 255B],[255B, 255B, 255B]]
  668.  
  669.     cycle = [[000B, 000B, 000B], [000B, 000B, 000B], [000B, 128B, 000B], $
  670.              [000B, 128B, 001B], [000B, 128B, 003B], [248B, 255B, 006B], $
  671.              [008B, 000B, 012B], [008B, 000B, 024B], [248B, 255B, 012B], $
  672.              [248B, 255B, 006B], [000B, 128B, 003B], [000B, 129B, 001B], $
  673.              [128B, 129B, 000B], [192B, 001B, 000B], [096B, 255B, 015B], $
  674.              [048B, 000B, 008B], [024B, 000B, 008B], [048B, 255B, 015B], $
  675.              [096B, 255B, 015B], [192B, 001B, 000B], [128B, 001B, 000B], $
  676.              [000B, 001B, 000B], [000B, 000B, 000B], [000B, 000B, 000B] ]
  677.  
  678.     cycleOn = [[255B, 255B, 255B], [255B, 255B, 255B], [255B, 127B, 255B], $
  679.                [255B, 127B, 254B], [255B, 127B, 252B], [007B, 000B, 249B], $
  680.                [247B, 255B, 243B], [247B, 255B, 231B], [007B, 000B, 243B], $
  681.                [007B, 000B, 249B], [255B, 127B, 252B], [255B, 126B, 254B], $
  682.                [127B, 126B, 255B], [063B, 254B, 255B], [159B, 000B, 240B], $
  683.                [207B, 255B, 247B], [231B, 255B, 247B], [207B, 000B, 240B], $
  684.                [159B, 000B, 240B], [063B, 254B, 255B], [127B, 254B, 255B], $
  685.                [255B, 254B, 255B], [255B, 255B, 255B], [255B, 255B, 255B] ]
  686.  
  687.     bitmapbutton = { Stop:stop, Forward:forward, $
  688.         Backward:backward, Cycle:cycle , $
  689.         ForwardOn : forwardOn, $
  690.         BackwardOn : backwardOn, $
  691.         CycleOn : cycleOn, StopOn : stopOn }
  692.  
  693.     RETURN, bitmapButton
  694.  
  695. end  ;  of InitBitmaspButton
  696.  
  697. ;---------------------------------------------------------------------------
  698. ;
  699. ;  Purpose:  This function  is a compound widget that creates the
  700. ;            animation tool for IDL 5.0. It returns the top level
  701. ;            base of this 
  702. ;
  703. ;            The main feature is the interactivity capability.
  704. ;            The object array of oMovableModelArray will be interactive
  705. ;            meaning that the object array can be rotated interactivily
  706. ;            with the clik-drag-release of the left mouse button
  707. ;            suring the animation.
  708. ; 
  709. ;            The object array in oStaticModelArray will not be interactive.
  710. ;            However, their content can be different for each frames.
  711. ;
  712. function CW_IAT, $
  713.     wTopBase, $               ; IN: parent base identifier
  714.     oStaticModelArray, $      ; IN: Model array that is not interactive
  715.     oMovableModelArray, $     ; IN: Model array that is interactive
  716.     oMovableModel, $          ; IN: translation model
  717.     oMovableRotationModel, $  ; IN: rotation model
  718.     oMovableScalingModel, $   : IN: scaling model
  719.     oView, $                  ; IN: view 
  720.     oTrack, $                 ; IN: trackball object (must be created outside )
  721.     oContainer, $             ; IN: container object (must be created outside )
  722.     nFrames, $                ; IN: number of frames.
  723.     Xsize = xsize, $          ; IN: (opt) drawing area x size (default =500) 
  724.     Ysize = ysize, $          ; IN: (opt) drawing area y size (default =425)
  725.     Reset = reset, $          ; IN: (opt) createa reset button if set to 1.
  726.     Status = status           ; OUT: returns 0 on failure, 1 on success
  727.  
  728.  
  729.     ;  Set status to OK.
  730.     ; 
  731.     status = 1
  732.  
  733.     ;  Verify that  all the parameters have been correctly
  734.     ;  passed.
  735.     ;
  736.     if (N_Params() NE 10) then begin
  737.         status = 0
  738.         Message, 'ERROR : 10 parameters must be passed to cw_iat.pro'
  739.     endif
  740.  
  741.     ;  Verify that the top level base is valid.
  742.     ;
  743.     check = WIDGET_INFO(wTopBase, /VALID_ID)
  744.     if (check NE 1) then begin
  745.         status = 0
  746.         Message, 'ERROR : Top level base identifer is not valid.'
  747.     endif
  748.  
  749.     ;  Set the default x and y size of the view area if not provided.
  750.     ;
  751.     if (N_ELEMENTS(xsize) EQ 0) then xsize = 500
  752.     if (N_ELEMENTS(ysize) EQ 0) then ysize = 425
  753.    
  754.     ;  Initialize the bitmap buttons (BitMap Button or BMB).
  755.     ;
  756.     BMB = InitBitmapButtons()
  757.  
  758.     ;  Create the cw base, child of the top level base(wTopBase).
  759.     ;
  760.     wCWBase = WIDGET_BASE(wTopBase, COLUMN=2, /FRAME)
  761.  
  762.        ;  Create a base for the left column.
  763.        ;  The left column contains functionality buttons.
  764.        ;
  765.        wLeftBase = WIDGET_BASE(wCWBase, /BASE_ALIGN_CENTER, $
  766.            /COLUMN)
  767.  
  768.            wButtonBase = WIDGET_BASE(wLeftBase, UVALUE='TIMER', /ROW)
  769.  
  770.                wPlayBButton = WIDGET_BUTTON(wButtonBase, $
  771.                    VALUE=BMB.backward, UVALUE='PLAYBACKWARD')
  772.  
  773.                wStopButton = WIDGET_BUTTON(wButtonBase, $
  774.                    VALUE=BMB.stopOn, UVALUE='STOP')
  775.  
  776.                wPlayFButton = WIDGET_BUTTON(wButtonBase, $
  777.                    VALUE=BMB.forward, UVALUE='PLAYFORWARD')
  778.  
  779.                wCycleButton = WIDGET_BUTTON(wButtonBase, $
  780.                    VALUE=BMB.cycle, UVALUE='CYCLE')
  781.  
  782.            wSpeedBase = WIDGET_BASE(wLeftBase, /COLUMN)
  783.  
  784.                wSpeedBaseLabel = WIDGET_LABEL(wSpeedBase, $
  785.                    VALUE = "Animation Speed:")
  786.  
  787.                wFramesSpeedBase = WIDGET_BASE(wSpeedBase, $
  788.                    TITLE = "Animation Speed", /COLUMN, /FRAME)
  789.  
  790.                    wFramesRateBase = WIDGET_BASE(wFramesSpeedBase, /ROW)
  791.  
  792.                        wFramesPerSecLabel = WIDGET_LABEL(wFramesRateBase, $
  793.                            VALUE = "Frames/Sec:")
  794.  
  795.                        wFramesRateLabel = WIDGET_LABEL(wFramesRateBase, $
  796.                            VALUE = '00.00 ')
  797.  
  798.                    wSliderBase = WIDGET_BASE(wFramesSpeedBase, $
  799.                        /COLUMN, /ALIGN_CENTER)
  800.  
  801.                        wfasttLbl = WIDGET_LABEL(wSliderBase, VALUE='Fast', $
  802.                            /ALIGN_CENTER)
  803.  
  804.                        wFramesSpeedSlider = WIDGET_SLIDER(wSliderBase,$
  805.                            /ALIGN_CENTER, $
  806.                            /DRAG, VALUE = 100, UVALUE='SPEED', $
  807.                            MAXIMUM = 100, MINIMUM = 0, /VERTICAL, $
  808.                            /SUPPRESS_VALUE)
  809.  
  810.                        wSlowLbl = WIDGET_LABEL(wSliderBase, VALUE='Slow', $
  811.                            /ALIGN_CENTER)
  812.  
  813.            wFrameBase = WIDGET_BASE(wLeftBase, /COLUMN)
  814.  
  815.                wFrameBaseLabel = WIDGET_LABEL(wFrameBase, $
  816.                    VALUE = "Animation Frame:")
  817.  
  818.                wFrameIndicatorBase = WIDGET_BASE(wFrameBase, $
  819.                    TITLE = "Animation Frame", /COLUMN, /FRAME)
  820.  
  821.                    wFramesIndicatorSlider = WIDGET_SLIDER(wFrameIndicatorBase, $
  822.                        /DRAG, VALUE = 0, UVALUE='INDICATOR', $
  823.                        MAXIMUM = nframes - 1, MINIMUM = 0)
  824.  
  825.                    wActiveButton = CW_BGROUP(wFrameIndicatorBase, $
  826.                        ['Active Slider'], UVALUE='ACTIVE', $
  827.                        FRAME=0, /NONEXCLUSIVE, /RETURN_INDEX, $
  828.                        SET_VALUE=0)                         ; inactive
  829.      
  830.         ;  Create the reset button if the reset keyword is set.
  831.         ;
  832.         if (N_ELEMENTS(reset) NE 0) then begin
  833.             wResetButton = WIDGET_BUTTON(wLeftBase, $
  834.                 VALUE='Reset', UVALUE='RESET')
  835.         endif else begin
  836.             wResetButton = 0L
  837.         endelse
  838.  
  839.         ;  Create a widget base for the right column.
  840.         ;  It contains the drawing area.
  841.         ;
  842.         wRightBase = WIDGET_BASE(wCWBase,/BASE_ALIGN_CENTER, /COLUMN)
  843.  
  844.             wAreaDraw = WIDGET_DRAW(wRightBase, XSIZE=xsize, $
  845.                 GRAPHICS_LEVEL=2, $
  846.                 YSIZE=ysize, /BUTTON_EVENTS, UVALUE='DRAWING', $
  847.                 RETAIN=0, /EXPOSE_EVENT, NOTIFY_REALIZE='Draw1CB')
  848.  
  849.     ;  Initial transform, to be used when reset.
  850.     ;
  851.     oMovableRotationModel->GetProperty, TRANSFORM=initTransform
  852.  
  853.     ;  Get the current time.
  854.     ;
  855.     starttime = systime(1)
  856.  
  857.     ;  Initialize the time delay between frames .
  858.     ;
  859.     delay = 2.0/(1.0 + 100.0)
  860.  
  861.     ;  Initialize the button flags.
  862.     ;
  863.     cycleFlag = 0        ; 0 = not in cycle mode, 1 = is in cycle mode
  864.     forwardFlag = 0      ; 0 = not in play forward mode, 1 = is
  865.     backwardFlag = 0     ; 0 = not in play forward mode, 1 = is
  866.     stopFlag = 1         ; 0 = playing, 1 = stopped
  867.     activeFlag = 0       ; 0 = frame indicator slider not active, 1 = active
  868.  
  869.     ;  Initialize the frame index and icrement.
  870.     ;
  871.     frameIndex = 0
  872.     frameIncrement = 1   ; 1 = play forward , -1 :  play backward
  873.     count = 0            ; for calculating the frame speed rate.
  874.     rate = 0.0
  875.  
  876.     vv = OBJARR(5)
  877.  
  878.     ;  Create the sState.vector. To retrieve it outside cw_iat, do this :
  879.     ;
  880.     ; child = WIDGET_INFO( wCWBASE, /CHILD)
  881.     ; WIDGET_CONTROL, child, GET_UVALUE = state
  882.     ; 
  883.     sState= { $
  884.         CurrentIndex: 0, $             ; Current frame index
  885.         PreviousIndex: 0, $            ; Previous frame index
  886.         btndown: 0b, $                 ; Mouse button: 0=down, other: not down
  887.         dragq: 2, $                    ; Drag quality: 0=low, 1=med. 2=high
  888.         facing: 'BOTH', $              ; Facing both sides
  889.         wAreaDraw: wAreaDraw, $        ; Widget draw ID
  890.         Delay : delay, $               ; Time delay between frames
  891.         OView: oView, $                ; View boject
  892.         OMovableModelArray:  $
  893.             oMovableModelArray, $      ; Models
  894.          OMovableModel: $ 
  895.             oMovableModel, $
  896.         OMovableRotationModel: $
  897.             oMovableRotationModel, $
  898.         OMovableScalingModel: $
  899.             oMovableScalingModel, $
  900.         OStaticModelArray: $
  901.             oStaticModelArray, $
  902.         OContainer: oContainer, $      ; Container object
  903.         OTrack: oTrack, $              ; Trackball object
  904.         WTopBase: wTopBase, $          ; Top level base, parent of wCWBase
  905.         WCWBase: wCWBase, $            ; Top base of cw_iat
  906.         WRightBase: wRightBase, $      ; Parent base of the draw widget ID
  907.         WButtonBase: wButtonBase, $    ; Parent base of the buttons ID
  908.         WLeftBase: wLeftBase, $        ; Left column base ID
  909.         WPlayBButton: wPlayBButton, $  ; Play backward button ID
  910.         WStopButton: wStopButton, $    ; Stop button ID
  911.         WPlayFButton: wPlayFButton, $  ; Play forward button ID
  912.         WCycleButton: wCycleButton, $  ; Play in cycle button ID
  913.         WResetButton: wResetButton, $  ; Rest button ID
  914.         WActiveButton: wActiveButton, $; Active button ID
  915.         WFramesSpeedSlider:  $
  916.             wFramesSpeedSlider, $      ; Animation speed slider ID
  917.         WFramesIndicatorSlider:  $
  918.             wFramesIndicatorSlider, $  ; Frame indicator slider ID
  919.         WFramesRateLabel: $ 
  920.             wFramesRateLabel, $        ; Animation speed label ID
  921.         Nframes: nframes, $            ; Number of frames
  922.         ActiveFlag : activeFlag, $     ; 0=active button off, 1=on
  923.         ForwardFlag : forwardFlag, $   ; Play forward mode: 0=no, 1=yes
  924.         BackwardFlag : backwardFlag, $ ; Play backward mode: 0=no, 1=yes
  925.         StopFlag : stopFlag, $         ; Animation stopped: 0=no, 1=yes 
  926.         CycleFlag : cycleFlag, $       ; Play in cycle: 0=no, 1=yes
  927.         InitTransform : initTransform, $ : Initial transformation
  928.         InitFlag : 0, $                ; Initial flag (1 only at start)
  929.         Count : count, $               ; Count the number of frames
  930.         Rate : rate, $                 ; Animation rate (frames per sec.)
  931.         FrameIndex : FrameIndex, $     ; Current frame index
  932.         FrameIncrement :  $
  933.              FrameIncrement, $         ; Frame index increment
  934.         BMB : BMB, $                   ; Bitmap buttons structure
  935.         StartTime : startTime, $       ; Start time
  936.         FinalTime : startTime $        ; final time (for animation speed)
  937.     }  
  938.  
  939.     ;  Set the sState.as the user value of the first child of
  940.     ;  cCWBase identifier.
  941.     ;  To have access to the 'sState. outside of this compound widget
  942.     ;  do this :
  943.     ;
  944.     ;  child = WIDGET_INFO(wCWBase, /CHILD)
  945.     ;  WIDGET_CONTROL, child, GET_UVALUE = sState. /NO_COPY
  946.     ;
  947.     WIDGET_CONTROL, wLeftBase, SET_UVALUE=sState, /NO_COPY
  948.  
  949.     WIDGET_CONTROL, wCWBase, EVENT_PRO = 'cw_iatEvent'
  950.  
  951.     RETURN, wCWBase
  952.  
  953. end  ; of cw_iat
  954.  
  955. ; -----------------------------------------------------------------------------
  956. ;
  957. ;  Purpose:   Create a vibrating membrane data.
  958. ;
  959. function vibmem, $
  960.     nFrames, $        ; IN:  number of frames
  961.     index             ; IN:  function index (0 =<  index < nFrames)
  962.  
  963.     nx = 21   ; x dimension of the data set.
  964.     ny = 21   ; y dimension of the data set.
  965.  
  966.     x = FIndGen(nx)/(nx-1)
  967.     y = FIndGen(ny)/(ny-1)
  968.  
  969.     x = x # Replicate(1.,ny)
  970.     y = Replicate(1.,nx) # y
  971.  
  972.     data = FLTARR(nx, ny)
  973.     ;  Mode
  974.     ;
  975.     i = 3
  976.     j = 2
  977.     z = sin(i*!Pi*x) * sin(j*!Pi*y)
  978.     
  979.     a = sin(FIndGen(nframes)*2*!Pi/nframes)
  980.     data =  z * a(index)
  981.  
  982.     RETURN, data
  983. end
  984.  
  985.  $Id: d_vibmembr.pro,v 1.19 1997/04/19 22:48:46 tremblay Exp $
  986. ;
  987. ;  Copyright (c) 1997, Research Systems, Inc. All rights reserved.
  988. ;       Unauthorized reproduction prohibited.
  989. ;
  990. ;+
  991. ;  FILE:
  992. ;       iniobj.pro
  993. ;
  994. ;  PURPOSE:
  995. ;       This procedure create the objects to be displayed
  996. ;       by the IDL 5.0 animation tool (CW_IAT)
  997. ;
  998. ;  CATEGORY:
  999. ;       IDL 5.0
  1000. ;
  1001. ;  CONTENTS:
  1002. ;       pro  iniobj      ; create and returns the objects.
  1003. ;
  1004. ;  NAMED STRUCTURES:
  1005. ;       initStr
  1006. ;
  1007. ;  COMMON BLOCS:
  1008. ;       none.
  1009. ;
  1010. ;  MODIFICATION HISTORY:
  1011. ;       9/96,   DAT   - Written.
  1012. ;-
  1013. ; -----------------------------------------------------------------------------
  1014. ;
  1015. ;  Purpose:  Function returns  the created objects.
  1016. ;
  1017. function iniobj, $
  1018.      nframes, $     ; IN: number of frames
  1019.      xdim, $        ; IN: x dimension of the data
  1020.      ydim, $        ; IN: y dimension of the data
  1021.      box = box      ; IN: (opt) box around the main objects.
  1022.  
  1023.     ;  Initialize parameters.
  1024.     ;
  1025.     boxhere = N_ELEMENTS(box)
  1026.  
  1027.     ; Set the view such that the surface is
  1028.     ; contained within a box defined by
  1029.     ; by radx and rady ( view normal coordinates)
  1030.     ;
  1031.     xAxis = -0.5      ; center the  axes
  1032.     yAxis = -0.5     
  1033.     zAxis = -0.5    
  1034.  
  1035.     sqr3 = sqrt(3)
  1036.     radx = 2.0   ; viewport in normal coor.
  1037.     rady = 2.0
  1038.     xv = (1.0 - sqr3) /(2.0 * radx)
  1039.     yv = (1.0 - sqr3) /(2.0 * rady)
  1040.     width = 1.0 - 2 * xv
  1041.     height = 1.0 - 2 * yv
  1042.     myview = [xv+xAxis, yv+yAxis, width, height] 
  1043.  
  1044.     ;  Create the view.
  1045.     ;
  1046.     oView = OBJ_NEW('idlgrview', PROJECTION=2, EYE=3, $
  1047.         ZCLIP=[1.5,-1.5], VIEW=myview, COLOR=[0,0,0])
  1048.  
  1049.     ;  Create the model tree.
  1050.     ;
  1051.     oTopModel = OBJ_NEW('idlgrmodel')
  1052.     oView->Add, oTopModel
  1053.     
  1054.     ;  Scale the top model to fit the viewing area.
  1055.     ;
  1056.     sct = 0.7
  1057.     oTopModel->Scale, sct, sct, sct
  1058.  
  1059.     oStaticModel = OBJ_NEW('idlgrmodel')
  1060.     oStaticRotationModel = OBJ_NEW('idlgrmodel')
  1061.     oStaticScalingModel = OBJ_NEW('idlgrmodel')
  1062.     oMovableModel = OBJ_NEW('idlgrmodel')
  1063.     oMovableRotationModel = OBJ_NEW('idlgrmodel')
  1064.     oMovableScalingModel = OBJ_NEW('idlgrmodel')
  1065.     oTopModel->Add, oMovableModel
  1066.     oMovableModel->Add, oMovableRotationModel
  1067.     oMovableRotationModel->Add, oMovableScalingModel
  1068.     oTopModel->Add, oStaticModel
  1069.     oStaticModel->Add, oStaticRotationModel
  1070.     oStaticRotationModel->Add, oStaticScalingModel
  1071.  
  1072.     ;  Create the model arrays (dimension is nFrames)
  1073.     ;
  1074.     oStaticModelArray = OBJARR(nframes)
  1075.     oMovableModelArray = OBJARR(nframes)
  1076.  
  1077.     for i = 0,nframes-1 do begin
  1078.         oStaticModelArray(i) = OBJ_NEW('idlgrmodel')
  1079.         oMovableModelArray(i) = OBJ_NEW('idlgrmodel')
  1080.         oStaticScalingModel->Add, oStaticModelArray(i)
  1081.         oMovableScalingModel->Add, oMovableModelArray(i)
  1082.         oMovableModelArray(i)->SetProperty, HIDE=1
  1083.     endfor
  1084.  
  1085.     ;  Create the surface data from the vibrating membrane
  1086.     ;  function.
  1087.     ;
  1088.     z = vibmem(nframes, 0)
  1089.     sz = SIZE(z)
  1090.     maxx = sz(1) - 1
  1091.     maxy = sz(2) - 1
  1092.     maxz = MAX(z, MIN=minz)
  1093.  
  1094.     ; Compute coordinate conversion to normalize.
  1095.     ;
  1096.     xs = [0+xAxis,1.0/maxx]
  1097.     ys = [0+yAxis,1.0/maxy]
  1098.  
  1099.     minz2 = minz - 1
  1100.     maxz2 = maxz + 1 
  1101.     zs = [-minz2/(maxz2-minz2)+zAxis, 1.0/(maxz2-minz2)]
  1102.  
  1103.     ; For height-fields, use the following vertex colors.
  1104.     ;
  1105.     xdimension = sz(1) 
  1106.     ydimension = sz(2)
  1107.     vertexColors = BYTARR(nframes,3,xdimension*ydimension,/nozero)
  1108.     cbins=[[255,   0,   0], $
  1109.            [255,  85,   0], $
  1110.            [255, 170,   0], $
  1111.            [255, 255,   0], $
  1112.            [170, 255,   0], $
  1113.            [ 85, 255,   0], $
  1114.            [  0, 255,   0]]
  1115.  
  1116.  
  1117.     ; Create the shades array.
  1118.     ; 
  1119.     shadesArray = FLTARR(nframes, xdimension, ydimension)
  1120.     shades2 = FLTARR(nframes, xdimension* ydimension)
  1121.     shades3 = FLTARR(nframes, xdimension* ydimension)
  1122.     temp = fltarr(xdimension, ydimension)
  1123.     zi = INTARR( 1,xdimension, ydimension)
  1124.     xtot = xdimension * ydimension
  1125.  
  1126.     ;  Shades array is  color corresponding to hte vibrating
  1127.     ;  membrane height (4-D mode).
  1128.     ;
  1129.     for i = 0, nframes-1 do begin
  1130.         temp = vibmem(nframes, i)
  1131.         shadesArray(i, 0:xdimension-1, 0:ydimension-1) = $
  1132.             temp(0:xdimension-1, 0:ydimension-1)
  1133.         shades2(i, 0:xtot-1) = temp(0:xdimension-1, 0:ydimension-1)
  1134.     endfor
  1135.  
  1136.     shadesArray2 = shadesArray
  1137.  
  1138.     ;  Shades array 2 is  color corresponding to the  bumps
  1139.     ;  function  ( 6-D mode).
  1140.     ;
  1141.     for i = 0, nframes-1 do begin
  1142.         temp = bumps(i + 40)   ; 40 is any indice for bumps function 
  1143.         shadesArray2(i, 0:xdimension-1, 0:ydimension-1) = $
  1144.             temp(0:xdimension-1, 0:ydimension-1)
  1145.         shades3(i, 0:xtot-1) = temp(0:xdimension-1, 0:ydimension-1)
  1146.     endfor
  1147.  
  1148.     maxshades = MAX(shadesArray, MIN = minshades)
  1149.  
  1150.     sat = 1.0
  1151.     val = 1.0
  1152.     maxangle = 225.0  ; ( angle is  0 < .. < 360 )
  1153.  
  1154.     ;  Create the actual vertexcolors array corresponding
  1155.     ;  to the vibrating membrane.
  1156.     ;
  1157.     for i = 0, nframes-1 do begin
  1158.         for j = 0, xtot-1 do begin
  1159.             angle =ROUND(  (shades2(i,j) - minshades) / $ 
  1160.                 (maxshades-minshades) * maxangle )  
  1161.              color_convert, angle, sat, val, red, green, blue, /hsv_rgb
  1162.              vertexColors(i, 0, j) = red
  1163.              vertexColors(i, 1, j) = green
  1164.              vertexColors(i, 2, j) = blue
  1165.         endfor
  1166.     endfor
  1167.  
  1168.     ;  Create the actual vertexcolors array corresponding
  1169.     ;  to the bumps function.
  1170.     ;
  1171.     vertexColors2 = vertexColors
  1172.  
  1173.     maxshades = MAX(shadesArray2, MIN = minshades)
  1174.  
  1175.     for i = 0, nframes-1 do begin
  1176.         for j = 0, xtot-1 do begin
  1177.             angle =ROUND(  (shades3(i,j) - minshades) / $ 
  1178.                 (maxshades-minshades) * maxangle )  
  1179.             color_convert, angle, sat, val, red, green, blue, /hsv_rgb
  1180.             vertexColors2(i, 0, j) = red
  1181.             vertexColors2(i, 1, j) = green
  1182.             vertexColors2(i, 2, j) = blue
  1183.         endfor
  1184.     endfor
  1185.  
  1186.     ; Create an obj array , Create 20 surfaces
  1187.     ;
  1188.     oWaveSurfaceArray = OBJARR(nframes)
  1189.     for i = 0, nframes-1 do begin
  1190.         oWaveSurfaceArray(i) = OBJ_NEW('IDLgrSurface', z, $
  1191.             STYLE=2, SHADING=0, COLOR=[60,60,255], BOTTOM=[64,192,128], $
  1192.            XCOORD_CONV=xs, YCOORD_CONV=ys, ZCOORD_CONV=zs)
  1193.         oMovableModelArray(i)->add,oWaveSurfaceArray(i)
  1194.         zt = vibmem(nframes, i)
  1195.         oWaveSurfaceArray(i)->setproperty, DATAZ=zt
  1196.     endfor
  1197.  
  1198.     ;  Create a box.
  1199.     ;
  1200.     x = [ 0, 0, 0, 0, 0, 1, 1, 0, 1, 1, 0, $
  1201.           1, 1, 0, 1, 1   ]
  1202.     y = [ 0, 0, 1, 1, 0, 0, 0, 0, 0, 1, 1, $
  1203.           1, 1, 1, 1, 0   ]
  1204.     z = [ 0, 1, 1, 0, 0, 0, 1, 1, 1, 1, 1, $
  1205.           1, 0, 0, 0, 0   ]
  1206.  
  1207.     x2 = [ 0.0, 0.0, 0.0, 0.0, 0.0]
  1208.     y2 = [ 0.0, 0.0, 0.0, 0.0, 0.0]
  1209.     z2 = [ 0.0, 0.0, 0.0, 0.0, 0.0]
  1210.     x3 = FINDGEN(5)
  1211.     y3 = FINDGEN(5)
  1212.     z3 = FINDGEN(5)
  1213.  
  1214.     if (box EQ 1) then begin
  1215.         olineArray = objarr(20)
  1216.         for i = 0, nframes-1 do begin
  1217.             olinearray(i) = OBJ_NEW('idlgrpolyline',x,y,z, $
  1218.             COLOR=[255,0,0], THICK=2)
  1219.             oStaticModelArray(i)->add,olinearray(i)
  1220.         endfor
  1221.     endif   ; of if  box
  1222.  
  1223.  
  1224.     ;  Create some light.
  1225.     ;
  1226.     m = OBJ_NEW('idlgrmodel')
  1227.     oLight1 = OBJ_NEW('IDLgrLight', LOC=[2,2,2], TYPE=1)
  1228.     m->add,oLight1
  1229.     oLight2 = OBJ_NEW('IDLgrLight', TYPE=0, INTENSITY=0.5)
  1230.     m->add,oLight2
  1231.     OView->add,m
  1232.  
  1233.  
  1234.     ;  Create a solid line style
  1235.     ;
  1236.     for i = 0, nframes-1 do begin
  1237.         oWaveSurfaceArray(i)->SetProperty, LINESTYLE=4294967295L
  1238.     endfor
  1239.  
  1240.     ;  Rotate and translate the surfaces
  1241.     ;  Show them one by one
  1242.     ;
  1243.     for i = 0, nframes-1  do begin
  1244.         oMovableModelArray(i)->rotate,[1,0,0],-90
  1245.         oMovableModelArray(i)->rotate,[0,1,0],30
  1246.         oMovableModelArray(i)->rotate,[1,0,0],30
  1247.     endfor
  1248.  
  1249.     ;  Get the initial transform, to be used when reset.
  1250.     ;
  1251.     oMovableModelArray(0)->GetProperty, TRANSFORM=initTransform
  1252.     oMovableModelArray(0)->GetProperty, TRANSFORM=t
  1253.  
  1254.     ;  Add the trackball object for interactive change
  1255.     ;  of the scene orientation.
  1256.     ;
  1257.     oTrack = OBJ_NEW('Trackball', [xdim/2.0, ydim/2.0], xdim/2.0)
  1258.  
  1259.     oContainer = OBJ_NEW('IDLgrContainer')
  1260.     oContainer->Add, oView
  1261.     oContainer->Add, oTrack
  1262.  
  1263.  
  1264.     ; Save information into the structure
  1265.     ;
  1266.     initStr = { $
  1267.         Nframes : nframes, $
  1268.         Xdim : xdim, $
  1269.         Ydim : ydim, $
  1270.         OTopModel: oTopModel, $
  1271.         OTrack: oTrack, $
  1272.         OContainer: oContainer, $
  1273.         OMovableModel: oMovableModel, $
  1274.         OMovableRotationModel: oMovableRotationModel, $
  1275.         OMovableScalingModel: oMovableScalingModel, $
  1276.         OMovableModelArray: oMovableModelArray, $
  1277.         OWaveSurfaceArray: oWaveSurfaceArray, $
  1278.         OView: oView, $
  1279.         OStaticModelArray: oStaticModelArray, $
  1280.         VertexColors: vertexColors, $
  1281.         VertexColors2: vertexColors2, $
  1282.         Xtot : xtot, $
  1283.         InitTransform : initTransform $
  1284.     }  
  1285.  
  1286.     RETURN, initStr 
  1287.  
  1288. end     ;   of iniobj.pro
  1289.  
  1290.  
  1291.  
  1292. pro vib_SetShades, $
  1293.     initial, $      ; IN: initial frame index
  1294.     final, $        ; IN: final frame index
  1295.     event           ; IN: event structure
  1296.  
  1297.     WIDGET_CONTROL, event.top, GET_UVALUE=info, /NO_COPY
  1298.  
  1299.     tempColor = INTARR( 3, info.xtot)
  1300.  
  1301.     if (initial LT final) then begin
  1302.         for i = initial, final do begin
  1303.             tempColor(0:2, 0:info.xtot-1) = $
  1304.                 info.vertexColors(i, 0:2, 0:info.xtot-1)
  1305.             info.oWaveSurfaceArray(i)->setproperty, $
  1306.                 VERT_COLORS=tempColor
  1307.         endfor
  1308.     endif else begin
  1309.         for i = initial, final, -1 do begin
  1310.             tempColor(0:2, 0:info.xtot-1) = $
  1311.                 info.vertexColors2(i, 0:2, 0:info.xtot-1)
  1312.             info.oWaveSurfaceArray(i)->setproperty, $
  1313.                 VERT_COLORS=tempColor
  1314.         endfor
  1315.     endelse
  1316.  
  1317.     info.drawWindowObjID->draw,info.oView
  1318.  
  1319.     WIDGET_CONTROL, event.top, SET_UVALUE=info, /NO_COPY
  1320.  
  1321. end   ; of vib_SetShades
  1322.  
  1323. ; -----------------------------------------------------------------------------
  1324. ;
  1325. ;  Purpose:  Toggle the vertex off and vertex on button.
  1326. ;
  1327. function Toggle_state, $
  1328.     wid          ;  IN: widget identifer
  1329.  
  1330.     WIDGET_CONTROL, wid, GET_VALUE = name
  1331.  
  1332.     s = STRPOS(name,'(off)')
  1333.  
  1334.     if (s NE -1) then begin
  1335.         strput,name,'(on )',s
  1336.         ret = 1
  1337.     endif else begin
  1338.         s = strpos(name,'(on )')
  1339.         strput,name,'(off)',s
  1340.         ret = 0
  1341.     endelse
  1342.  
  1343.     WIDGET_CONTROL, wid, SET_VALUE = name
  1344.  
  1345.     RETURN, ret
  1346. end
  1347.  
  1348. ; -----------------------------------------------------------------------------
  1349. ;
  1350. ;  Purpose:  Main event handler.
  1351. ;
  1352. pro vibmembr_event, $
  1353.     event      ; IN: event structure
  1354.  
  1355.     ;  Quit the application using the close box.
  1356.     ;
  1357.     if (TAG_NAMES(event, /STRUCTURE_NAME) EQ $
  1358.         'WIDGET_KILL_REQUEST') then begin
  1359.         WIDGET_CONTROL, event.top, /DESTROY
  1360.         RETURN
  1361.     endif
  1362.  
  1363.     ;  Open a widget message if the user try to quit
  1364.     ;  using the close box (not the quit button of the application).
  1365.     ;
  1366.     if (TAG_NAMES(Event, /STRUCTURE_NAME) eq 'WIDGET_KILL_REQUEST') $
  1367.         then begin
  1368.         v = WIDGET_MESSAGE('Use the File/Quit menu item to ' + $
  1369.             'close this application.')
  1370.     endif
  1371.  
  1372.  
  1373.     case WIDGET_INFO(event.id,/NAME) of
  1374.  
  1375.         ; Now handle the button events
  1376.         ;
  1377.         'BUTTON' : begin
  1378.  
  1379.             ;  Get the event user value and branch to that event.
  1380.             ;
  1381.             WIDGET_CONTROL, event.id, GET_UVALUE=uval
  1382.  
  1383.             case uval of
  1384.  
  1385.                 ;  Change the surface into a wire style.
  1386.                 ;
  1387.                 'WIRE' : begin
  1388.                     WIDGET_CONTROL, event.top, GET_UVALUE=info, /NO_COPY
  1389.                     stylestring = 'Wire'
  1390.                     info.stylestring = 'Wire'
  1391.  
  1392.                     for i = 0, info.nframes-1  do begin
  1393.                         info.oWaveSurfaceArray(i)->SetProperty, STYLE=1
  1394.                     endfor
  1395.  
  1396.                     info.dragq = 0
  1397.                     info.drawWindowObjID->SetProperty, QUALITY=info.dragq
  1398.                     info.drawWindowObjID->Draw, info.oView    
  1399.                     WIDGET_CONTROL, info.wSolidButton, SENSITIVE=1
  1400.                     WIDGET_CONTROL, info.wWireButton, SENSITIVE=0
  1401.                     WIDGET_CONTROL, event.top, SET_UVALUE=info, /NO_COPY
  1402.                 end  ; of WIRE
  1403.  
  1404.                 ;  Change the surface into a solid style.
  1405.                 ;
  1406.                 'SOLID' : begin
  1407.                     WIDGET_CONTROL, event.top, GET_UVALUE=info, /NO_COPY
  1408.                     stylestring = 'Solid'
  1409.                     info.stylestring = 'Solid'
  1410.  
  1411.                     for i = 0, info.nframes-1  do begin
  1412.                         info.oWaveSurfaceArray(i)->SetProperty, STYLE=2
  1413.                     endfor
  1414.  
  1415.                     WIDGET_CONTROL, info.wSolidButton, SENSITIVE=0
  1416.                     WIDGET_CONTROL, info.wWireButton, SENSITIVE=1
  1417.  
  1418.                     if (info.dragq EQ 0) then begin
  1419.                         info.dragq = 2
  1420.                         info.drawWindowObjID->SetProperty, QUALITY=info.dragq
  1421.                     endif else if (info.dragq EQ 1) then begin
  1422.                         WIDGET_CONTROL, info.wMediumButton, sensitive = 0
  1423.                     endif else begin
  1424.                         WIDGET_CONTROL, info.wHighButton, sensitive = 0
  1425.                     endelse
  1426.  
  1427.                     info.drawWindowObjID->draw,info.oView    
  1428.                     WIDGET_CONTROL, event.top, SET_UVALUE=info, /NO_COPY
  1429.  
  1430.                 end  ;     of  SOLID
  1431.  
  1432.                 ;  Change the shading to flat.
  1433.                 ;
  1434.                 'FLAT' : begin
  1435.                     WIDGET_CONTROL, event.top, GET_UVALUE=info, /NO_COPY
  1436.                     shadingstring = 'Flat'
  1437.                     info.shadingstring = 'Flat'
  1438.  
  1439.                     for i = 0, info.nframes-1  do begin
  1440.                         info.oWaveSurfaceArray(i)->SetProperty, SHADING=0
  1441.                     endfor
  1442.  
  1443.                     info.drawWindowObjID->draw,info.oView    
  1444.                     WIDGET_CONTROL, info.wFlatButton, SENSITIVE=0
  1445.                     WIDGET_CONTROL, info.wGouraudButton, SENSITIVE=1
  1446.                     WIDGET_CONTROL, event.top, SET_UVALUE=info, /NO_COPY
  1447.  
  1448.                 end  ;     of  FLAT
  1449.  
  1450.                 ;  Change the shading to Gouraud.
  1451.                 ;
  1452.                 'GOURAUD' : begin
  1453.                      WIDGET_CONTROL, event.top, GET_UVALUE=info, /NO_COPY
  1454.  
  1455.                     for i = 0, info.nframes-1  do begin
  1456.                         info.oWaveSurfaceArray(i)->SetProperty, SHADING=1
  1457.                     endfor
  1458.  
  1459.                     info.drawWindowObjID->draw,info.oView    
  1460.                     shadingstring = 'Gouraud'
  1461.                     info.shadingstring = 'Gouraud'
  1462.                     WIDGET_CONTROL, info.wFlatButton, SENSITIVE=1
  1463.                     WIDGET_CONTROL, info.wGouraudButton, SENSITIVE=0
  1464.                     WIDGET_CONTROL, event.top, SET_UVALUE=info, /NO_COPY
  1465.  
  1466.                 end  ;     of  GOURAUD
  1467.  
  1468.                 ;  Change the surface to show 4 dimensions.
  1469.                 ;
  1470.                 'FOURD' : begin
  1471.  
  1472.                     ;  If the vertex colors are on, set the shade 
  1473.                     ;  frames in order,
  1474.                     ;  hence showing the surface height.
  1475.                     ;
  1476.                     WIDGET_CONTROL, event.top, GET_UVALUE=info, /NO_COPY
  1477.                     WIDGET_CONTROL, info.wNoColorButton, SENSITIVE=1
  1478.                     WIDGET_CONTROL, info.wFourDButton, SENSITIVE=0
  1479.                     WIDGET_CONTROL, info.wFiveDButton, SENSITIVE=1
  1480.                     nframes = info.nframes
  1481.  
  1482.                     nFrames = info.nFrames
  1483.                     WIDGET_CONTROL, event.top, SET_UVALUE=info, /NO_COPY
  1484.                     vib_SetShades, 0, nframes-1, event
  1485.  
  1486.                 end  ;     of  FOURD
  1487.  
  1488.                 ;  Change the surface to show 5 dimensions.
  1489.                 ;
  1490.                 'FIVED' : begin
  1491.  
  1492.                     ;  Set the shades colors to show the
  1493.                     ;  'bumps' function values.
  1494.                     ;  Toggle the vertex color button to on.
  1495.                     ;
  1496.                     WIDGET_CONTROL, event.top, GET_UVALUE=info, /NO_COPY
  1497.  
  1498.                     WIDGET_CONTROL, info.wNoColorButton, SENSITIVE=1
  1499.                     WIDGET_CONTROL, info.wFourDButton, SENSITIVE=1
  1500.                     WIDGET_CONTROL, info.wFiveDButton, SENSITIVE=0
  1501.  
  1502.                     nFrames = info.nFrames
  1503.                     WIDGET_CONTROL, event.top, SET_UVALUE=info, /NO_COPY
  1504.                     vib_SetShades, nframes-1, 0, event
  1505.  
  1506.                 end  ;     of  FIVED
  1507.  
  1508.                 ;  Set the surface to be monochromatic (one color).
  1509.                 ;
  1510.                 'NOCOLOR' : begin
  1511.  
  1512.                     WIDGET_CONTROL, event.top, GET_UVALUE=info, /NO_COPY
  1513.  
  1514.                     WIDGET_CONTROL, info.wNoColorButton, SENSITIVE=0
  1515.                     WIDGET_CONTROL, info.wFourDButton, SENSITIVE=1
  1516.                     WIDGET_CONTROL, info.wFiveDButton, SENSITIVE=1
  1517.  
  1518.  
  1519.                     tempColor = INTARR( 3, info.xtot)
  1520.                     topColor = INTARR(3)
  1521.                     bottomColor = INTARR(3)
  1522.                     info.oWaveSurfaceArray(0)->getproperty, COLOR=topColor
  1523.                     info.oWaveSurfaceArray(0)->getproperty, BOTTOM=bottomColor
  1524.                     nframes = info.nframes
  1525.       
  1526.                     for i = 0, info.nframes-1 DO begin
  1527.                         info.oWaveSurfaceArray(i)->SetProperty, $
  1528.                             VERT_COLORS=0
  1529.                         info.oWaveSurfaceArray(i)->SetProperty, $
  1530.                             COLOR=topColor
  1531.                         info.oWaveSurfaceArray(i)->SetProperty, $
  1532.                             BOTTOM=bottomColor
  1533.                     endfor
  1534.  
  1535.                     info.drawWindowObjID->draw,info.oView
  1536.                     WIDGET_CONTROL, event.top, SET_UVALUE=info, /NO_COPY
  1537.  
  1538.                 end   ; of NOCOLOR
  1539.  
  1540.                 ;  Set drag quality to low.
  1541.                 ;
  1542.                 'LOW' : begin
  1543.                     WIDGET_CONTROL, event.top, GET_UVALUE=info, /NO_COPY
  1544.                     child = WIDGET_INFO( info.wCWBase, /CHILD)
  1545.                     WIDGET_CONTROL, child, GET_UVALUE = state, /NO_COPY
  1546.                     info.dragq = 0
  1547.                     state.dragq = 0
  1548.                     WIDGET_CONTROL, child, SET_UVALUE = state, /NO_COPY
  1549.                     WIDGET_CONTROL, info.wLowButton, SENSITIVE=0
  1550.                     WIDGET_CONTROL, info.wMediumButton, SENSITIVE=1
  1551.                     WIDGET_CONTROL, info.wHighButton, SENSITIVE=1
  1552.                     WIDGET_CONTROL, event.top, SET_UVALUE=info, /NO_COPY
  1553.                 end   ; of  LOW
  1554.  
  1555.                 ;  Set drag quality to medium.
  1556.                 ;
  1557.                 'MEDIUM' : begin
  1558.                     WIDGET_CONTROL, event.top, GET_UVALUE=info, /NO_COPY
  1559.                     child = WIDGET_INFO( info.wCWBase, /CHILD)
  1560.                     WIDGET_CONTROL, child, GET_UVALUE = state, /NO_COPY
  1561.                     info.dragq = 1
  1562.                     state.dragq = 1
  1563.                     WIDGET_CONTROL, child, SET_UVALUE = state, /NO_COPY
  1564.                     WIDGET_CONTROL, info.wLowButton, SENSITIVE=1
  1565.                     WIDGET_CONTROL, info.wMediumButton, SENSITIVE=0
  1566.                     WIDGET_CONTROL, info.wHighButton, SENSITIVE=1
  1567.                     WIDGET_CONTROL, event.top, SET_UVALUE=info, /NO_COPY
  1568.                 end   ; of  MEDIUM
  1569.  
  1570.                 ;  Set drag quality to high.
  1571.                 ;
  1572.                 'HIGH' : begin
  1573.                     WIDGET_CONTROL, event.top, GET_UVALUE=info, /NO_COPY
  1574.                     child = WIDGET_INFO( info.wCWBase, /CHILD)
  1575.                     WIDGET_CONTROL, child, GET_UVALUE = state, /NO_COPY
  1576.                     info.dragq = 2
  1577.                     state.dragq = 2
  1578.                     WIDGET_CONTROL, child, SET_UVALUE = state, /NO_COPY
  1579.                     WIDGET_CONTROL, info.wLowButton, SENSITIVE=1
  1580.                     WIDGET_CONTROL, info.wMediumButton, SENSITIVE=1
  1581.                     WIDGET_CONTROL, info.wHighButton, SENSITIVE=0
  1582.                     WIDGET_CONTROL, event.top, SET_UVALUE=info, /NO_COPY
  1583.                 end   ; of  HIGH
  1584.  
  1585.                 ;  Display the information file.
  1586.                 ;
  1587.                 'INFO' : begin
  1588.                     if (Xregistered('XDisplayFile') NE 0) then RETURN
  1589.                     XDisplayFile, filepath("vibmembr.txt", $
  1590.                         SUBDIR=['examples', 'demo', 'demotext']), $
  1591.                         DONE_BUTTON='Done', $
  1592.                         TITLE="About intereactive 6-D visualizations", $
  1593.                         GROUP=event.top, WIDTH=55, HEIGHT=14
  1594.                 end   ; of  INFO
  1595.  
  1596.                 ;  Quit thie application.
  1597.                 ;
  1598.                 'QUIT' : begin
  1599.                     WIDGET_CONTROL, event.top, /DESTROY
  1600.                     RETURN
  1601.                 end   ; of  QUIT
  1602.  
  1603.             endcase  ; of case uval in BUTTON
  1604.  
  1605.         end   ; of BUTTON case
  1606.  
  1607.         ELSE :   ; do nothing
  1608.  
  1609.     endcase   ; of case widget_info(name)
  1610.  
  1611. end  ; of vibmembr_event
  1612.  
  1613. ; -----------------------------------------------------------------------------
  1614. ;
  1615. ;  Purpose:   Cleanup procedure. Destroy the objects and
  1616. ;             restore the previous color table.
  1617. ;
  1618. pro vibmembr_cleanup, $
  1619.     wTopBase         ; IN: top level base identifier
  1620.  
  1621.     WIDGET_CONTROL, wTopBase, GET_UVALUE=info, /NO_COPY
  1622.  
  1623.     ;  Restore the color table
  1624.     ;
  1625.     TVLCT, info.colorTable
  1626.  
  1627.     ;  Destroy the top objects
  1628.     ;
  1629.     OBJ_DESTROY, info.oView
  1630.  
  1631.     OBJ_DESTROY, info.oTrack
  1632.     OBJ_DESTROY, info.oContainer
  1633.  
  1634.     ;  Map the group leader base if it exists.
  1635.     ;
  1636.     if (WIDGET_INFO(info.groupBase, /VALID_ID)) then $
  1637.         WIDGET_CONTROL, info.groupBase, /MAP
  1638.  
  1639. end ; of vibmembr_cleanup
  1640.  
  1641. ; -----------------------------------------------------------------------------
  1642. ;
  1643. ;  Purpose:   Animate a series of surface objects (in IDL 5.0).
  1644. ;             The scheme is to precompute the surface height for
  1645. ;             n frames. The 'animation' is made by displaying
  1646. ;             successively each frames ( or objects)
  1647. ;
  1648. pro d_vibmembr, $
  1649.     Box = box, $       ; IN: (opt) create a box arou d the surface
  1650.     GROUP=group, $     ; IN: (opt) Group leader
  1651.     APPTLB = appTLB    ; OUT: (opt) TLB of this application
  1652.  
  1653.     ; Check the validity of the group identifier.
  1654.     ;
  1655.     ngroup = N_ELEMENTS(group)
  1656.     if (ngroup NE 0) then begin
  1657.         check = WIDGET_INFO(group, /VALID_ID)
  1658.         if (check NE 1) then begin
  1659.             print,'Error, the group identifier is not valid'
  1660.             print, 'Return to the main application'
  1661.             RETURN
  1662.         endif
  1663.         groupBase = group
  1664.     endif else groupBase = 0L
  1665.  
  1666.     checkBox = N_ELEMENTS(box)
  1667.  
  1668.     ;  Save the color table
  1669.     ;
  1670.     TVLCT, savedR, savedG, savedB, /GET
  1671.     colorTable = [ [savedR], [savedG], [savedB] ]
  1672.  
  1673.  
  1674.     ;  Make the system to have a maximum of 256 colors.
  1675.     ;
  1676.     if ((( !D.NAME EQ 'X') OR (!D.NAME EQ 'MAC')) $
  1677.        AND (!D.N_COLORS GE 256L)) then $
  1678.        DEVICE, PSEUDO_COLOR=8
  1679.     
  1680.     DEVICE, DECOMPOSED=0, BYPASS_TRANSLATION=0
  1681.  
  1682.     ;  Determine hardware display size.
  1683.     ;
  1684.     DEVICE, GET_SCREEN_SIZE=screenSize
  1685.  
  1686.     ;  Make the drawing area proportional to the 
  1687.     ;  screen size.
  1688.     ;
  1689.     drawXSize = 0.6 * screenSize(0)
  1690.     drawYSize = 0.8 * drawXSize
  1691.  
  1692.     ;  Get the tips.
  1693.     ;
  1694.     sText = getTips(filepath('vibmembr.tip', $
  1695.         SUBDIR=['examples','demo', 'demotext']) )
  1696.  
  1697.     ;  Initialize parameter / constants
  1698.     ;
  1699.     nframes = 20     ; number of frames 
  1700.     reset = 1         ; have a reset button in the compound widget)
  1701.     xdim = drawXSize
  1702.     ydim = drawYSize
  1703.  
  1704.     ;  Initialize all the objects
  1705.     ;
  1706.     objectStr = iniobj(nframes, xdim, ydim, Box = checkbox)
  1707.  
  1708.     ;  Create widgets.
  1709.     ;
  1710.     if (ngroup EQ 0) then begin
  1711.         wTopBase = WIDGET_BASE(/COLUMN, $
  1712.             TLB_FRAME_ATTR=1, MBAR=barbase, $
  1713.             XPAD=0, YPAD=0, $
  1714.             /TLB_KILL_REQUEST_EVENTS, $
  1715.             TITLE="Vibrating Membrane")
  1716.     endif else begin
  1717.         wTopBase = WIDGET_BASE(/COLUMN, $
  1718.             GROUP_LEADER=parent, $
  1719.             XPAD=0, YPAD=0, $
  1720.             TLB_FRAME_ATTR=1, MBAR=barbase, $
  1721.             /TLB_KILL_REQUEST_EVENTS, $
  1722.             TITLE="Vibrating Membrane")
  1723.     endelse
  1724.  
  1725.         ;  Create the file menu bar item that contains the quit button.
  1726.         ;
  1727.         wFileButton = WIDGET_BUTTON(barbase,Value = 'File', /MENU)
  1728.  
  1729.             wQuitButton = WIDGET_BUTTON(wFileButton, $
  1730.                 VALUE='Quit', UVALUE='QUIT')
  1731.  
  1732.         ;  Create the option menu .
  1733.         ;
  1734.         wOptionButton = WIDGET_BUTTON(barbase, VALUE='Options', /MENU)
  1735.  
  1736.             wStyleButton = WIDGET_BUTTON(wOptionButton, $
  1737.                 VALUE='Style', UVALUE='Style', /MENU)
  1738.  
  1739.                 wWireButton = WIDGET_BUTTON(wStyleButton, $
  1740.                     VALUE='Wire', UVALUE='WIRE')
  1741.  
  1742.                 wSolidButton = WIDGET_BUTTON(wStyleButton, $
  1743.                     VALUE='Solid', UVALUE='SOLID')
  1744.  
  1745.             wShadingButton = WIDGET_BUTTON(wOptionButton, $
  1746.                 VALUE='Shading', UVALUE='Shading', /MENU)
  1747.  
  1748.                 wFlatButton = WIDGET_BUTTON(wShadingButton, $
  1749.                     VALUE='Flat', UVALUE='FLAT')
  1750.  
  1751.                 wGouraudButton = WIDGET_BUTTON(wShadingButton, $
  1752.                     VALUE='Gouraud', UVALUE='GOURAUD')
  1753.  
  1754.             wQualityButton = WIDGET_BUTTON(wOptionButton, $
  1755.                 VALUE='Drag Quality', UVALUE='QUALITY', /MENU)
  1756.  
  1757.                 wLowButton = WIDGET_BUTTON(wQualityButton, $
  1758.                     VALUE='Low', UVALUE='LOW')
  1759.  
  1760.                 wMediumButton = WIDGET_BUTTON(wQualityButton, $
  1761.                     VALUE='Medium', UVALUE='MEDIUM')
  1762.  
  1763.                 wHighButton = WIDGET_BUTTON(wQualityButton, $
  1764.                     VALUE='High', UVALUE='HIGH')
  1765.  
  1766.             wVertexButton = WIDGET_BUTTON(wOptionButton, $
  1767.                 VALUE='Vertex Colors', /MENU, UVALUE='VERTEX')
  1768.  
  1769.                 wNoColorButton = WIDGET_BUTTON(wVertexButton, $
  1770.                     VALUE='Monochromatic', UVALUE='NOCOLOR')
  1771.  
  1772.                 wFourDButton = WIDGET_BUTTON(wVertexButton, $
  1773.                     VALUE='4 Dimensions', UVALUE='FOURD')
  1774.  
  1775.                 wFiveDButton = WIDGET_BUTTON(wVertexButton, $
  1776.                     VALUE='5 Dimensions', UVALUE='FIVED')
  1777.  
  1778.  
  1779.         ;  Create the menu bar item help that contains the about button.
  1780.         ;
  1781.         wHelpButton = WIDGET_BUTTON(barbase,Value = 'About', /HELP, /Menu)
  1782.  
  1783.             wAboutButton = WIDGET_BUTTON(wHelpButton, $
  1784.                 VALUE='About Vibrating Membrane', UVALUE='INFO')
  1785.  
  1786.         ;  Call the compound widget that creates the core
  1787.         ;  of the animation tool.
  1788.         ;
  1789.         wCWBase = cw_iat(wTopBase, $
  1790.             objectStr.oStaticModelArray, objectStr.oMovableModelArray, $
  1791.             objectStr.oMovableModel, objectStr.oMovableRotationModel, $
  1792.             objectStr.oMovableScalingModel, $
  1793.             objectStr.oView,  $
  1794.             objectStr.oTrack, $
  1795.             objectStr.oContainer, nframes, $
  1796.             XSIZE=xdim, YSIZE=ydim, $
  1797.             RESET=reset, STATUS=cwStatus)
  1798.  
  1799.         ;  Check the status of the cw_iat
  1800.         ;
  1801.         if (cwStatus EQ 0) then begin 
  1802.             MESSAGE,'The creation of the compound widget was not successful'
  1803.             RETURN
  1804.         endif
  1805.  
  1806.         ;  Create tips texts.
  1807.         ;
  1808.         wStatusBase = WIDGET_BASE(wTopBase, MAP=0, /ROW)
  1809.  
  1810.             nWidgets = 2
  1811.             wText = LONARR(nWidgets)
  1812.             widTips, wStatusBase, sText.text, XSIZE=36, $
  1813.                 YSIZE=3, NWIDGETS=nWidgets, wText
  1814.  
  1815.     ;  Now, all the widget have been created....
  1816.     ;  Realize the widget hierarchy.
  1817.     ;
  1818.     WIDGET_CONTROL, wTopBase, /REALIZE
  1819.  
  1820.     ;  Returns the top level base to the APPTLB keyword.
  1821.     ;
  1822.     appTLB = wtopBase
  1823.  
  1824.     ;  Size the tips widgets.
  1825.     ;
  1826.     sizeTips, wTopBase, wText, wStatusBase
  1827.  
  1828.     ;  Get the info structure of the compound widget  CW_IAT
  1829.     ;
  1830.     child = WIDGET_INFO( wCWBase, /CHILD)
  1831.     WIDGET_CONTROL, child, GET_UVALUE = state, /NO_COPY
  1832.  
  1833.     ;  Get the base that has the TIMER user value.
  1834.     ;  Make the stop flag to 0 ( not stopped)
  1835.     ;  so that we can animate at start up.
  1836.     ;
  1837.     wButtonBase = state.wButtonBase
  1838.     state.stopFlag = 0
  1839.  
  1840.     ;  Get the window object  of CW_IAT.
  1841.     ;
  1842.     wAreaDraw = state.wAreaDraw
  1843.     WIDGET_CONTROL, state.wRightBase, GET_UVALUE = temp, /NO_COPY
  1844.     drawWindowObjID = temp
  1845.     WIDGET_CONTROL, state.wRightBase, SET_UVALUE = temp, /NO_COPY
  1846.  
  1847.     ;  Desensitize the frame indicator slider.
  1848.     ;
  1849.     WIDGET_CONTROL, state.wFramesIndicatorSlider, SENSITIVE=0
  1850.  
  1851.     ;  Set the play forward button on, and the stop to off.
  1852.     ;
  1853.     WIDGET_CONTROL, state.wStopButton, SET_VALUE=state.BMB.stop
  1854.     WIDGET_CONTROL, state.wPlayFButton, SET_VALUE=state.BMB.forwardOn
  1855.  
  1856.     ;  Show each seperate frames.
  1857.     ;
  1858.     tempColor = INTARR( 3, objectStr.xtot)
  1859.     for i = 0, nframes-1 do begin
  1860.         objectStr.oMovableModelArray(i)->SetProperty, HIDE=0
  1861.         objectStr.oWaveSurfaceArray(i)->SetProperty, SHADING=1
  1862.  
  1863.             tempColor(0:2, 0:objectStr.xtot-1) = $
  1864.                 objectStr.vertexColors(i, 0:2, 0:objectStr.xtot-1)
  1865.  
  1866.         objectStr.oWaveSurfaceArray(i)->SetProperty, $
  1867.             VERT_COLORS=tempColor
  1868.         drawWindowObjID->draw,objectStr.oView
  1869.         objectStr.oMovableModelArray(i)->SetProperty, HIDE=1
  1870.         WIDGET_CONTROL, state.wFramesIndicatorSlider, SET_VALUE=i
  1871.     endfor
  1872.  
  1873.  
  1874.     ;  Set the frame indicator slider to 0.
  1875.     ;
  1876.     WIDGET_CONTROL, state.wFramesIndicatorSlider, $
  1877.        SET_SLIDER_MAX=nframes-1
  1878.     WIDGET_CONTROL, state.wFramesIndicatorSlider, SET_VALUE=0
  1879.  
  1880.     ;  Get the drag quality as set by cw_iat.
  1881.     ;  And the compound widget toplevel base ID.
  1882.     ;
  1883.     wCWBase = state.wCWBase
  1884.     dragq = state.dragq
  1885.  
  1886.     ;  Sensitize the compound widget.
  1887.     ;
  1888.     WIDGET_CONTROL, child, SET_UVALUE=state, /NO_COPY
  1889.     WIDGET_CONTROL, wCWBase, SENSITIVE=1
  1890.  
  1891.     ;  Create the info structure of the main application.
  1892.     ;
  1893.     info = { $
  1894.         dragq: dragq, $                     ; Drag quality: 0=low, 1=med. 2=high
  1895.         ColorTable: colorTable, $           ; Color table to restore
  1896.         facing: 'BOTH', $                   ; Showing both sides
  1897.         wAreaDraw: wAreaDraw, $             ; Widget draw ID
  1898.         OWaveSurfaceArray:  $
  1899.             objectStr.oWaveSurfaceArray, $  ; Surface object array
  1900.         OView: objectStr.oView, $           ; Main view object
  1901.         OTrack: objectStr.oTrack, $         ; Trackball object
  1902.         OContainer: objectStr.oContainer, $ ; Container object
  1903.         oStaticModelArray: $
  1904.             objectStr.oStaticModelArray, $  ; Models
  1905.         OMovableModelArray: $
  1906.             objectStr.oMovableModelArray, $
  1907.         OMovableModel:  $
  1908.             objectStr.oMovableModel, $
  1909.         OMovableRotationModel: $
  1910.             objectStr.oMovableRotationModel, $
  1911.         OMovableScalingModel: $
  1912.             objectStr.oMovableScalingModel, $
  1913.         VertexColors: $
  1914.             objectStr.vertexColors, $       ; Vertices colors (4-D)
  1915.         VertexColors2:  $
  1916.             objectStr.vertexColors2, $      ; Vertices colors (5-D)
  1917.         DrawWindowObjID: drawWindowObjID, $ ; Window object
  1918.         Barbase : barbase, $                ; Menu bar base ID
  1919.         WTopBase: wTopBase, $               ; Top level base
  1920.         WCWBase: wCWBase, $                 ; Compound widget top level base
  1921.         WQuitButton: wQuitButton, $         ; Functionality button IDs
  1922.         WWireButton: wWireButton, $
  1923.         WSolidButton: wSolidButton, $
  1924.         WFlatButton: wFlatButton, $
  1925.         WGouraudButton: wGouraudButton, $
  1926.         WNoColorButton: wNoColorButton, $
  1927.         WFourdButton: wFourDButton, $
  1928.         WFivedButton: wFiveDButton, $
  1929.         WVertexButton: wVertexButton, $
  1930.         WLowButton: wLowButton, $
  1931.         WMediumButton: wMediumButton, $
  1932.         WHighButton: wHighButton, $
  1933.         Stylestring : 'Solid', $            ; String indicating the style
  1934.         Shadingstring : 'Flat', $           ; String indicating the shading
  1935.         Nframes: nframes, $                 ; Number of frames
  1936.         Xtot : objectStr.xtot, $            ; Product of x dim by y dim of data set.
  1937.         groupBase: groupBase $              ; Base of Group Leader
  1938.      } 
  1939.  
  1940.    WIDGET_CONTROL, wTopBase, SET_UVALUE=info, /NO_COPY
  1941.  
  1942.    ;  Desensitize the stop button.
  1943.    ;
  1944.    WIDGET_CONTROL, wFourDButton, SENSITIVE=0
  1945.    WIDGET_CONTROL, wGouraudButton, SENSITIVE=0
  1946.    WIDGET_CONTROL, wSolidButton, SENSITIVE=0
  1947.  
  1948.    ;  Desensitize the medium and high drag quality buttons.
  1949.    ;
  1950.    WIDGET_CONTROL, wLowButton, SENSITIVE=1
  1951.    WIDGET_CONTROL, wMediumButton, SENSITIVE=1
  1952.    WIDGET_CONTROL, wHighButton, SENSITIVE=0    ; this was set in cw_iat
  1953.  
  1954.    ;  Make the kill request sensitive. This make the
  1955.    ;  event created by the quit and close button from
  1956.    ;  the opreating system to be gently recognied and processed.
  1957.    ;
  1958.    WIDGET_CONTROL, wTopBase,/TLB_KILL_REQUEST_EVENTS
  1959.  
  1960.    objectStr.oMovableModelArray(0)->SetProperty, HIDE=0
  1961.    objectStr.oStaticModelArray(0)->SetProperty, HIDE=0
  1962.  
  1963.     ;  Animate at start.
  1964.     ;
  1965.     pseudoEvent = { $
  1966.         ID: wButtonBase, $
  1967.         Top: wTopBase, $
  1968.         Handler:wCWBAse $
  1969.     }
  1970.     cw_iatEvent, pseudoEvent 
  1971.  
  1972.    XMANAGER, 'd_vibmembr', wTopBase, EVENT_HANDLER='vibmembr_event', $
  1973.        CLEANUP='vibmembr_cleanup', /NO_BLOCK
  1974.  
  1975. end
  1976.